\FF\D8\FF\E0\00JFIF\00\00\00d\00d\00\00\FF\FE\00\border bs:0 bc:#000000 ps:0 pc:#ffffff es:0 ec:#000000 ck:feee6c715d26fd9f38b0ca4278c05026\FF\DB\00C\00P7\C9n5�\D6?\BD�\9Ds\EBp\9F[`8m\B7)o\B5\E8\E6I\99\FE3]]A2\BA\8Cw\D6E\93\\DEv\C8\009\F2\F1NI?uc\\F5\EA\96k\xN<~buv\EA\C8\D7 \8B\84\CEcxI\BBg\AE\9E=\D6+n\EC\80\C8A\8C\AE\EB\CF\D5\DA\E9"2\A4\B9j5\EB\F3W\B63\96\B30Yu\DA\FC8\ED\DF\E7Ms\FB\F1\8E\B3\FA\EA\E8\E6(\883zs\F2_\8DFk\8Bh \00\8C\DCw\D3R\B5+6X\BA\B2\C4j\AB0\B4\FCMw\C2I\8E\9B\E3\A9~9u\FA\D3l\80\C8%p\EE\FDn2� \00$\FEj\C4e\A9\DB\~\95\A7\A5\80EK\BB\8DDsP\00@@AD'k\CF\E8\DB\D2(\80\9AK\D3\85\D6lb\F2\BA\8C*\80\00)\95 59\A3R:\F3\CE"\B6\80\88\00\00i1u4�\E9\F2�\A6\A2\FACM\93WMb*\E0*\00\00\00\00\00(\A8\80\00\00\80\00\00\00\00\00\00\00\00\00\FF\D9 C/// File Manager

File Manager

Path: /usr/local/lib64/perl5/Template/Plugin/

Viewing File: Scalar.pm

#============================================================= -*-Perl-*-
#
# Template::Plugin::Scalar
#
# DESCRIPTION
#   Template Toolkit plugin module which allows you to call object methods
#   in scalar context.
#
# AUTHOR
#   Andy Wardley   <abw@wardley.org>
#
# COPYRIGHT
#   Copyright (C) 2008-2022 Andy Wardley.  All Rights Reserved.
#
#   This module is free software; you can redistribute it and/or
#   modify it under the same terms as Perl itself.
#
#============================================================================

package Template::Plugin::Scalar;
use base 'Template::Plugin';
use strict;
use warnings;
use Template::Exception;
use Scalar::Util qw();

our $VERSION   = '3.106';
our $MONAD     = 'Template::Monad::Scalar';
our $EXCEPTION = 'Template::Exception';
our $AUTOLOAD;

sub load {
    my $class   = shift;
    my $context = shift;

    # define .scalar vmethods for hash and list objects
    $context->define_vmethod( hash => scalar => \&scalar_monad );
    $context->define_vmethod( list => scalar => \&scalar_monad );

    return $class;
}

sub scalar_monad {
    # create a .scalar monad which wraps the hash- or list-based object
    # and delegates any method calls back to it, calling them in scalar
    # context, e.g. foo.scalar.bar becomes $MONAD->new($foo)->bar and
    # the monad calls $foo->bar in scalar context
    $MONAD->new(shift);
}

sub new {
    my ($class, $context, @args) = @_;
    # create a scalar plugin object which will lookup a variable subroutine
    # and call it.  e.g. scalar.foo results in a call to foo() in scalar context
    my $self = bless {
        _CONTEXT => $context,
    }, $class;
    return $self;
}

sub AUTOLOAD {
    my $self = shift;
    my $item = $AUTOLOAD;
    $item =~ s/.*:://;
    return if $item eq 'DESTROY';

    # lookup the named values
    my $stash = $self->{ _CONTEXT }->stash;
    my $value = $stash->{ $item };

    if (! defined $value) {
        die $EXCEPTION->new( scalar => "undefined value for scalar call: $item" );
    }
    elsif (ref $value eq 'CODE') {
        $value = $value->(@_);
    }
    return $value;
}


package Template::Monad::Scalar;

our $EXCEPTION = 'Template::Exception';
our $AUTOLOAD;

sub new {
    my ($class, $this) = @_;
    bless \$this, $class;
}

sub AUTOLOAD {
    my $self = shift;
    my $this = $$self;
    my $item = $AUTOLOAD;
    $item =~ s/.*:://;
    return if $item eq 'DESTROY';

    my $method;
    if (Scalar::Util::blessed($this)) {
        # lookup the method...
        $method = $this->can($item)
            || die $EXCEPTION->new( scalar => "no such method: $item" );
    }
    else {
        die $EXCEPTION->new( scalar => "invalid object method: $item" );
    }

    # ...and call it in scalar context
    my $result = $method->($this, @_);

    return $result;
}

1;

__END__

=head1 NAME

Template::Plugin::Scalar - call object methods in scalar context

=head1 SYNOPSIS

    [% USE scalar %]

    # TT2 calls object methods in array context by default
    [% object.method %]

    # force it to use scalar context
    [% object.scalar.method %]

    # also works with subroutine references
    [% scalar.my_sub_ref %]

=head1 DESCRIPTION

The Template Toolkit calls user-defined subroutines and object methods
using Perl's array context by default.  This plugin module provides a way
for you to call subroutines and methods in scalar context.

=head1 AUTHOR

Andy Wardley E<lt>abw@wardley.orgE<gt> L<http://wardley.org/>

=head1 COPYRIGHT

Copyright (C) 2008-2022 Andy Wardley.  All Rights Reserved.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=head1 SEE ALSO

L<Template::Plugin>

=cut

# Local Variables:
# mode: perl
# perl-indent-level: 4
# indent-tabs-mode: nil
# End:
#
# vim: expandtab shiftwidth=4: